Filters and searching for objects, the Res buffer, (3.1) the Cell buffer

#declare your variables for querying
var @QueryPos, %IsQuerying

# declare your variables for the search and modify
var $BoardName, ~Board, %Board
var ~Boarda, $BoardDes

# initialise variables in your code
# the object you look for has in the action field
# 'create name board'
$BoardName = "name board"
# the bot is not yet querying
%IsQuerying = 0

# somewhere in your code, you decide to look for
# your board object at a certain place 
# for instance, where the bot is,
# and change its description
# you must first query the zone
# get the bot's position
GetLocation @QueryPos
# install the event handlers for the query
OnQueryCompleteEvent Complete
OnWorldReconnectEvent Reconnect
# start your query
%IsQuerying = 1
QueryAt @QueryPos
# loop until QueryComplete
Label WaitForQuery
IfInt %IsQuerying = 1 Goto WaitForQuery
# your new description, probably best assigned in a Sub,
# must now be assigned (here just an example)
$BoardDes = "And the winner is XXX !"
# Change the board sign
Gosub MakeBoard
# ~Boarda's object number is automatically updated.
# in this case, because we are dealing with one object
# and not building from within an event handler
# the update is guaranteed to follow the build satement.
# Otherwise, you must install the event handler for ObjectCreate
# and assign the new object to ~Board in the handler and not here
~Board = ~Boarda
# To make sure your object is modified,
# you may install the ObjectResult handler
# (not explained here).
# Once your bot has the object, and has modified it,
# if you are certain no one else will alter the object,
# you may omit the query bit
# next time the bot must alter the object.
# Next time you wish to modify,
# just assign the new description
# $BoardDes = "something here...."
# call Gosub MakeBoard
# followed by ~Board = ~Boarda
#...
End


# in the events and subs section
# for querying

Event Complete
   %IsQuerying = 0
EndEvent

Event Reconnect
   IfInt %IsQuerying = 1 QueryAt @QueryPos
EndEvent

# this Sub finds the first instance of your object
# IfGetResObjectItem ~Board 1

Sub FindBoard
   FilterClear
   ResClear
   FilterAction $BoardName
   ResFromSurveyFilter
   IfGetResObjectItem ~Board 1 %Board = 1
   Else %Board = 0
EndSub

# To modify the description on ~Board and change it to $BoardDes:

Sub MakeBoard
   Gosub FindBoard
   IfInt %Board = 0 Goto MakeBoardError
   ~Boarda = ~Board
   GetDescription ~Boarda $BoardDes
   ObjectModify ~Board ~Boarda
   EndSub
   Label MakeBoardError
   Say Can't find my board :(
EndSub